2. Ardunio

Arduino Engellerden Kaçan Robot

 Yayınlanma : 02-09-2024 | 18 : 12 04
 Güncelleme : 02-09-2024 | 18 : 12 04
Haber Görseli

Ultrasonik bir sensör kullanılarak Arduino tarafından kodlanan bu robot, genelde popülerdir. Çok basittir ve az sayıda modül kullanır.

Genel bakış :

Arduino engelden kaçınan robot araba, yolundaki engelleri ultrasonik bir sensör, özellikle HC-SR04 modeli kullanarak tespit etmek üzere tasarlanmıştır.
       Robot sürekli olarak ileriye doğru hareket eder ve bir engelle karşılaştığında hareketini durdurur. Sistem daha sonra ultrasonik sensörü döndürmek için bir servo motor kullanır ve bu sayede her iki tarafı da tarayabilir ve daha az engele sahip daha net bir yol belirleyebilir.
      Bu dinamik engel kaçınma mekanizması robotun uyarlanabilirliğini artırarak, çeşitli engel derecelerine sahip ortamlarda verimli bir şekilde hareket etmesini sağlar.

Gerekli Bileşenler :

  1. Arduino Uno veya uyumlu kart
  2. DC motorlu 4 tekerlekli şasi kiti
  3. L298N motor sürücü modülü
  4. Ultrasonik sensör (HC-SR04)
  5. SG90 servo motor (biz MG90S kullandık) 
  6. Bağlantı kabloları
  7. Üç adet 18650 Şarj Edilebilir Pil 3.7V
  8. 18650 Li-ion Pil Tutucu 3 Yollu
  9. Açma kapama Anahtarı
  10. Arduino'yu programlamak için USB kablosu
  11. Tornavida ve çeşitli vidalar
  12. Mini veya Orta Breadboard

 

MOTORLARIN L298N MOTOR SÜRÜCÜSÜNE BAĞLANMASI : 

Bu şekilde dişli motorların kablolarını l298N motor sürücüsünün motor güç konnektörlerine bağlayın.

  • Sağdaki iki motoru birbirine resimdeki gibi bağlayın. Kırmızı kablosunu L298N motor sürücüsünün "OUT1" terminallerine bağlayın.
  • Sağdaki Siyah motor kablosunu motor sürücüsündeki "OUT2" terminallerine bağlayın.
  • Sol taraftaki iki motoru birbirine resimdeki gibi bağlayın. Kırmızı motor kablosunu motor sürücüsündeki "OUT3" terminallerine bağlayın.
  • Soldaki siyah motor kablosunu motor sürücüsündeki "OUT4" terminallerine bağlayın.

 

Pil Güç Bağlantısını Bağlayın :

L298N Motor sürücü üzerinde sırası ile 12V - GND - 5 V bağlantı yeri vardır. 
- 3 adet 2600ma 3,7v 18650 lipo pil ve yuvası kullanıldı. Pil yuvası üzerindeki kırmızı kablonun bir ucu açma kapama butonuna lehimlendi. 
- Butonun diğer ucuna da başka bir kırmızı kablo lehimleyerek diğer ucunu 12v yazan kısıma bağlandı. 
- Pil yuvasındaki siyah kablo L298N motor sürücü üzerindeki GND yazan kısıma bağlandı. Bu kısıma bir adet daha siyah kablo bağlandı Ardunio uno kartı üzerindeki GND yazan pin yuvasına bağlandı. 
Ortak kullanımlar için bu gerekli.

 

Arduino kartı L298N Motor sürücüsü ile güçlendirilmiştir .
Eğer Ardunio kartı için lazım olan gücü L298N Motor sürücüsünden almak istersek aşağıdaki gibi bağlantıları yaparız. Almayacak isek GND bağlantısı ortak kullanım için zaten yapılmalı.

  • Motor sürücüsünün 5V Çıkış konnektörünü Arduino üzerindeki VIN pinine bağlayın.
  • Motor sürücüsünün GND konnektörünü Arduino üzerindeki GND pinine bağlayın.

 

L298N Motor Sürücüsünün dört girişinin Arduino UNO kartına bağlanması. 

 
Her motorun kontrol sinyalleri Arduino veya mikrodenetleyiciden gelir. Her motor için iki giriş pimi vardır (bir motor için IN1/IN2 ve diğeri için IN3/IN4). Bu pimlere farklı yüksek ve düşük sinyal kombinasyonları uygulayarak Arduino her motorun yönünü ve hızını kontrol eder.

L298N'de kullanıcının ilgili H köprüsünü etkinleştirmesine veya devre dışı bırakmasına izin veren iki etkinleştirme pimi (ENA ve ENB) bulunur. Motorların hızını kontrol etmek için bu pimlere PWM (Darbe Genişlik Modülasyonu) sinyalleri uygulanabilir. Burada ENA ve ENB kullanmıyorum. 5V'a bağlı bir mini jumper'ı var.

 

Bu şekilde Arduino kartının dijital pinlerini ve L298N motor sürücüsünün girişlerini jumper kabloları ile birbirine bağlayacağız.

  • Motor sürücüsünün IN1 pinini Arduino üzerindeki dijital pin 4'e bağlayın.
  • Motor sürücüsünün IN2 pinini Arduino üzerindeki dijital pin 5'e bağlayın.
  • Motor sürücüsünün IN3 pinini Arduino üzerindeki dijital pin 6'ya bağlayın.
  • Motor sürücüsünün IN4 pinini Arduino üzerindeki dijital pin 7'ye bağlayın.

 SG90 / MG90S Servo motor bağlantıları : 

Bu şekilde Arduino kartınızı ve SG90 Servo motorunuzu jumper kabloları ile birbirine bağlayın.

  • Servo motordan gelen Sinyali (Sarı / Turuncu Kablo) Arduino üzerindeki 10 dijital pinine bağlayın.
  • Servo motordan gelen VCC'yi (Kırmızı Kablo) Arduino'daki 5V pinine bağlayın. Biz resimdeki gibi mini breadboarda bağladık.
  • Servo motordan gelen GND (Kahverengi Kablo)'yu Arduino üzerindeki GND pinine bağlayın. Biz resimdeki gibi mini breadboarda bağladık.

Ultrasonik sensörün (HC-SR04) Arduino kartına bağlanması

Bu şekilde ultrasonik sensörü (HC-SR04) Arduino kartına bağlayın,

  • Ultrasonik sensörün VCC (güç) pinini Arduino üzerindeki 5V pinine bağlayın. Biz resimdeki gibi mini breadboarda bağladık.
  • Sensörün GND (toprak) pinini Arduino üzerindeki GND pinine bağlayın. Biz resimdeki gibi mini breadboarda bağladık.
  • Ultrasonik sensörün TRIG (tetik) pinini Arduino üzerindeki Analog pin A1'e bağlayın.
  • Sensörün ECHO pinini Arduino üzerindeki diğer Analog pin A2'ye bağlayın.

 

İLGİLİ KOD:

Burada New Ping ve Servo kütüphanesini kullandık. Bu kütüphaneyi kullanmak için Arduino IDE'deki Kütüphane Yöneticisini açın ve oradan yükleyin.

 
#include <Servo.h>
#include <NewPing.h>

//our L298N control pins
const int SolMotorIleri = 7;// turuncu - in 4 pembe
const int SolMotorGeri = 6; // sarı in3 - yeşil
const int SagMotorGeri = 5; // yeşil // in2 gri
const int SagMotorIleri = 4; // mavi  in1 - turuncu

//sensor pins
#define trig_pin A1 //analog input 1 turuncu
#define echo_pin A2 //analog input 2 sarı
#define maximum_mesafe 200
boolean ileriYuru = false;
int mesafe = 100; // mesafe
NewPing sonar(trig_pin, echo_pin, maximum_mesafe); //sensor fonksiyon
Servo servo_motor; //  servo degisken

void setup() {
  
  pinMode(SagMotorIleri, OUTPUT);
  pinMode(SolMotorIleri, OUTPUT);
  pinMode(SolMotorGeri, OUTPUT);
  pinMode(SagMotorGeri, OUTPUT);

 
  servo_motor.attach(10); // servo pin
  servo_motor.write(115);
  delay(2000);
  mesafe = mesOku();
  delay(100);
  mesafe = mesOku();
  delay(100);
  mesafe = mesOku();
  delay(100);
  mesafe = mesOku();
  delay(100);
}

void loop() {
  
  int sagMesafe = 0;
  int solMesafe = 0;
  delay(50);
if (mesafe <= 45){
    hopDur();
    delay(300);
    geriGit();
    delay(400);
    hopDur();
    delay(300);
    sagMesafe = sagaBak();
    delay(300);
    solMesafe = solaBak();
    delay(300);
    if (mesafe >= solMesafe){
      sagaDon();
      hopDur();
    }
    else{
      solaDon();
      hopDur();
    }
  }
  else{
    ileriGit();
  }
    mesafe = mesOku();
}
int sagaBak(){
 
  servo_motor.write(50);
  delay(500);
  int mesafe = mesOku();
  delay(100);
  servo_motor.write(115);
  return mesafe;
}
int solaBak(){

  servo_motor.write(170);
  delay(500);
  int mesafe = mesOku();
  delay(100);
  servo_motor.write(115);
  return mesafe;
  delay(100);
}
int mesOku(){
  delay(70);
  int cm = sonar.ping_cm();
  if (cm==0){
    cm=250;
  }
  return cm;
}

void hopDur(){
  digitalWrite(SagMotorIleri, LOW);
  digitalWrite(SolMotorIleri, LOW);
  digitalWrite(SagMotorGeri, LOW);
  digitalWrite(SolMotorGeri, LOW);
 
}
void ileriGit(){
  if(!ileriYuru){
    ileriYuru=true;//ileri gidiyor true
    digitalWrite(SolMotorIleri, HIGH);
    digitalWrite(SagMotorIleri, HIGH);
    digitalWrite(SolMotorGeri, LOW);
    digitalWrite(SagMotorGeri, LOW);
  }
}
void geriGit(){
  ileriYuru=false;
  digitalWrite(SolMotorGeri, HIGH);
  digitalWrite(SagMotorGeri, HIGH);
  digitalWrite(SolMotorIleri, LOW);
  digitalWrite(SagMotorIleri, LOW);
}
void sagaDon(){
  digitalWrite(SolMotorIleri, HIGH);
  digitalWrite(SagMotorGeri, HIGH);
  digitalWrite(SolMotorGeri, LOW);
  digitalWrite(SagMotorIleri, LOW);
  delay(250);
  digitalWrite(SolMotorIleri, HIGH);
  digitalWrite(SagMotorIleri, HIGH);
  digitalWrite(SolMotorGeri, LOW);
  digitalWrite(SagMotorGeri, LOW);
}
void solaDon(){
  digitalWrite(SolMotorGeri, HIGH);
  digitalWrite(SagMotorIleri, HIGH);
  digitalWrite(SolMotorIleri, LOW);
  digitalWrite(SagMotorGeri, LOW);
  delay(250);
  digitalWrite(SolMotorIleri, HIGH);
  digitalWrite(SagMotorIleri, HIGH);
  digitalWrite(SolMotorGeri, LOW);
  digitalWrite(SagMotorGeri, LOW);
}

SONUÇ :
 
 


Haber : 


Mobil Facebook paylaşımında haber bağlantısı görünmüyorsa:
  1. Haber sayfasını Chrome veya normal tarayıcınızda açın.
  2. Tarayıcının sağ üst köşesindeki üç nokta (⋮) menüsüne dokunun.
  3. Menüden Paylaş seçeneğini seçin.
  4. Açılan listeden Facebook veya Facebook Lite uygulamasına dokunun.

Bu yöntemle haber bağlantısı, başlığı ve kapak görseli paylaşımınıza doğru şekilde eklenir.

ETİKETLER : Yazdır

  Yorumlar

Yorumlar, editörlerimiz tarafından onaylandıktan sonra yayınlanır. Kanunlara aykırı, konuyla ilgisi olmayan, küfür içeren yorumlar onaylanmamaktadır.

 Yorumlar ( 0 )

Henüz bir yorum yapılmamış